If ismember(StrComputername & "$","OfficePrinter") then
showstat("Mapping COLOR Laser Printer") 
objNetwork.AddWindowsPrinterConnection "\\printServer\COLOR-LASER"
End if

quote:

---

Script \\server\folder\logon.vbs
Line: 40
Char: 1
Error:Object doesn't support this property or method: 'document.all.scrolling'
Code: 800A01B6
Source: Microsoft VBScript runtime error

---

Dim objNetwork
Set objNetwork = CreateObject("Wscript.Network")

Dim strUsername
strUsername = objNetwork.Username

objNetwork.MapNetworkDrive "Q:", "\\server\privatedata\" & strUsername

showstat("Mapping H: for HomeDirectory") 
  If Not MapDrive("H:", "\\server\privatedata\" & strUserName) Then
    MsgBox "Unable to Map H: to HomeDirectory"
  End If

If IsMember("IT") Then
	showstat("Mapping N: for downloads") 
	If Not MapDrive("N:", "\\studenthousing.com\root\downloads") Then
		MsgBox "Unable to Map N: to Downloads"
	End If
End If

'************************************************************************
'*** ACC VBS Login Script ***
'************************************************************************
' Last modified 1/18/05

Dim objNetwork, objSysInfo, strUserDN
Dim objGroupList, objUser, objFSO
Dim strComputerDN, objComputer,objShell
Dim STRLOGONSERVER
Dim computername, strusername,strComputername,colUserEnvVars,colEnvVars,struserprofile,vfile
Dim WshNetwork, asdPath
Dim strMappedDrives, strStatus,struser
Dim IE,objWMIService,strcomputer,GroupDN,arrTemp,GroupCN
Set objNetwork = CreateObject("Wscript.Network")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objSysInfo = CreateObject("ADSystemInfo")
Set objShell = WScript.CreateObject("WScript.Shell")
Set colEnvVars = objShell.Environment("User")
struserprofile = objShell.ExpandEnvironmentStrings("%USERPROFILE%")
strlogonserver = objShell.ExpandEnvironmentStrings("%logonserver%")
strUserDN = objSysInfo.userName
strComputerDN = objSysInfo.computerName
strUserName = ucase((objNetwork.UserName))
strcomputername = ucase((objnetwork.computername))
Set objUser = GetObject("LDAP://" & strUserDN)
Set objComputer = GetObject("LDAP://" & strComputerDN)
Set objShell = Wscript.CreateObject("Wscript.Shell")
DIM strmessage
' Get the User ID
Set WSHNetwork = WScript.CreateObject("WScript.Network")
strUser = ""
While strUser = ""
	struser = WSHNetwork.UserName
Wend

On error resume next

Call CreateIE()
showstat("Logon Script v1.2 " & Date() & " " & Time())
ie.document.all.scrolling.InnerText = "Please wait while your logon script runs."
ie.document.all.msg1.InnerText = strUser
ie.document.all.msg2.InnerText = strComputername

call main()

ie.document.all.scrolling.InnerText = "Network Logon Completed..."
showstat("Script Completed")
' Close IE status window
If not ie.document.all.holdit.checked then
ie.quit()
End if

' *********************************************************
' *** Create IE Status Window ***
' *********************************************************
Sub CreateIE()
On Error Resume Next
Set IE = CreateObject("InternetExplorer.Application")
With IE
.navigate "\\"&strlogonserver&"\netlogon\logon.htm"
.resizable=0
.height=600
.width=450
.menubar=0
.toolbar=0
.statusBar=0
.visible=1
End With
Do while ie.Busy
' wait for page to load
	Wscript.Sleep 100
Loop

End Sub


Sub Main()

' *********************************************************
' *** Run Trend OfficeScan Client ***
' *********************************************************
' Runs the OfficeScan Updater in the background. (No DOS box is displayed to the user)

showstat("Updating Virus Definition Files")
objShell.Run "cmd /c \\avmon1\OFCSCAN\AUTOPCC",0
objShell.Run "cmd /c \\core2\netlogon\ofcpfwsvc_kill.bat",0


' ***********************************************************
' *** Map Common Network Drives ***
' ***********************************************************

showstat("Mapping K: for Publicdata") 
If Not MapDrive("K:", "\\fileserver1\publicdata") Then
	MsgBox "Unable to Map K: to Publicdata"
End If

showstat("Mapping J: for Privatedata") 
If Not MapDrive("J:", "\\fileserver1\privatedata\" & strUserName) Then
	MsgBox "Unable to Map J: to Privatedata"
End If

showstat("Mapping P: for Propertydata") 
If Not MapDrive("P:", "\\studenthousing.com\root\propertydata") Then
	MsgBox "Unable to Map P: to Propertydata"
End if


' ***********************************************************
' *** Private Network Drive Mappings ***
' ***********************************************************
' Map certain drives based on group membership

If IsMember("Graphic Design") Then
	showstat("Mapping M: for Graphic Design") 
	If Not MapDrive("M:", "\\studenthousing.com\root\graphicdesign") Then
		MsgBox "Unable to Map M: to Accounting"
	End If
End If

If IsMember("SOX") Then
	showstat("Mapping S: for SOX") 
	If Not MapDrive("S:", "\\studenthousing.com\root\SOX") Then
		MsgBox "Unable to Map S: to SOX"
	End If
End If

If IsMember("Timberline") Then
	showstat("Mapping R: for Checks") 
	If Not MapDrive("R:", "\\fileserver1\checks") Then
		MsgBox "Unable to Map R: to Checks"
	End If
End If

If IsMember("Timberline") Then
	showstat("Mapping T: for Timberline") 
	If Not MapDrive("T:", "\\acct1\timberline") Then
		MsgBox "Unable to Map T: to Timberline"
	End If
End If

If IsMember("Timberline") Then
	showstat("Mapping G: for Mlink") 
	If Not MapDrive("G:", "\\acct1\mlink5") Then
		MsgBox "Unable to Map G: to Mlink"
	End If
End If

If IsMember("payroll") Then
	showstat("Mapping Y: for Payroll") 
	If Not MapDrive("Y:", "\\hr1\ADPBK") Then
		MsgBox "Unable to Map Y: to Payroll"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping O: for ISOS") 
	If Not MapDrive("O:", "\\studenthousing.com\root\isos") Then
		MsgBox "Unable to Map O: to ISOS"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping L: for Images") 
	If Not MapDrive("L:", "\\studenthousing.com\root\images") Then
		MsgBox "Unable to Map L: to Images"
	End If
End If

If IsMember("Datacenter") Then
	showstat("Mapping W: for ITOps") 
	If Not MapDrive("W:", "\\studenthousing.com\root\itops") Then
		MsgBox "Unable to Map M: to ITOps"
	End If
End If

If IsMember("CS") Then
	showstat("Mapping W: for ITOps") 
	If Not MapDrive("W:", "\\studenthousing.com\root\itops") Then
		MsgBox "Unable to Map M: to ITOps"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping V: for Password Database") 
	If Not MapDrive("V:", "\\studenthousing.com\root\pwddb") Then
		MsgBox "Unable to Map V: to Password Database"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping H: for Track-It") 
	If Not MapDrive("H:", "\\studenthousing.com\root\track-it") Then
		MsgBox "Unable to Map H: to Track-It"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping I: for IT Docs") 
	If Not MapDrive("I:", "\\studenthousing.com\root\it_docs") Then
		MsgBox "Unable to Map I: to IT Docs"
	End If
End If

If IsMember("IT") Then
	showstat("Mapping N: for downloads") 
	If Not MapDrive("N:", "\\studenthousing.com\root\downloads") Then
		MsgBox "Unable to Map N: to Downloads"
	End If
End If

' *********************************
' *** End of Drive Mappings ***
' *********************************

' Norton does NOT like the objShell.Run command and will flag your script. Avoid using these if
' you have Norton security on the desktop

' This will clear out the DNS cache, and make sure the workstation registers with the DNS server.
showstat( "Flushing DNS cache") 
objShell.Run "cmd /c ipconfig /flushdns",0
objShell.Run "cmd /c ipconfig /registerdns",0

End Sub ' MAIN

' Clean up and clear out some variables
Set objNetwork = Nothing
Set objFSO = Nothing
Set objSysInfo = Nothing
Set objGroupList = Nothing
Set objUser = Nothing
Set objComputer = Nothing

' showstat adds comments to the status window, and updates the IE display.
Function showstat(strmessage)
strstatus=strmessage + VBCRLF + strstatus 
ie.document.all.wstatus.InnerText = strstatus
end function

' IsMember is a boolean function to determine group membership.
Function IsMember(strGroup)
' Function to test for group membership,
' returns True if the user or computer is a member of the group.

If IsEmpty(objGroupList) Then
Call LoadGroups
End If
IsMember = objGroupList.Exists(strGroup)
End Function

Sub LoadGroups
' Subroutine to populate dictionary object with group memberships.
' objUser is the user or computer object, with global scope.
' objGroupList is a dictionary object, with global scope.

Dim arrbytGroups, j, arrstrGroupSids(), objGroup

Set objGroupList = CreateObject("Scripting.Dictionary")
objGroupList.CompareMode = vbTextCompare

objUser.GetInfoEx Array("tokenGroups"), 0
arrbytGroups = objUser.Get("tokenGroups")
If TypeName(arrbytGroups) = "Byte()" Then
ReDim arrstrGroupSids(0)
arrstrGroupSids(0) = OctetToHexStr(arrbytGroups)
Set objGroup = GetObject("LDAP://<SID=" & arrstrGroupSids(0) _
& ">")
objGroupList(objGroup.sAMAccountName) = True
Set objGroup = Nothing
Exit Sub
End If
If UBound(arrbytGroups) = -1 Then
Exit Sub
End If

ReDim arrstrGroupSids(UBound(arrbytGroups))
For j = 0 To UBound(arrbytGroups)
arrstrGroupSids(j) = OctetToHexStr(arrbytGroups(j))
Set objGroup = GetObject("LDAP://<SID=" & arrstrGroupSids(j) _
& ">")
objGroupList(objGroup.sAMAccountName) = True
Next
Set objGroup = Nothing
End Sub

Function MapDrive(strDrive, strShare)
' Function to map network share to a drive letter.
' If the drive letter specified is already in use, the function
' attempts to remove the network connection.
' objFSO is the File System Object, with global scope.
' objNetwork is the Network object, with global scope.
' Returns True if drive mapped, False otherwise.

Dim objDrive

On Error Resume Next
Err.Clear
If objFSO.DriveExists(strDrive) Then
Set objDrive = objFSO.GetDrive(strDrive)
If Err.Number <> 0 Then
Err.Clear
MapDrive = False
Exit Function
End If
If CBool(objDrive.DriveType = 3) Then
objNetwork.RemoveNetworkDrive strDrive, True, True
Else
MapDrive = False
Exit Function
End If
Set objDrive = Nothing
End If
objNetwork.MapNetworkDrive strDrive, strShare
If Err.Number = 0 Then
MapDrive = True
Else
Err.Clear
MapDrive = False
End If
On Error GoTo 0
End Function

Function OctetToHexStr(arrbytOctet)
' Function to convert OctetString (byte array) to Hex string.

Dim k
OctetToHexStr = ""
For k = 1 To Lenb(arrbytOctet)
OctetToHexStr = OctetToHexStr _
& Right("0" & Hex(Ascb(Midb(arrbytOctet, k, 1))), 2)
Next
End Function

'**************************************************************
'***			Acme Corp VBS Login Script    			    ***
'**************************************************************
' Last modified 03/10/08 Joe Admin
'Option Explicit
'On Error Goto 0
On error resume next
Dim objNetwork, objSysInfo, WshNetwork
Dim objGroupList, objUser, objFSO
Dim strComputerDN, objComputer,objShell
Dim strLogonServer,strOS, strStatus, strErrMsg
Dim strUser,strUserName,strComputerName,strUserDN
Dim colUserEnvVars,colEnvVars,strUserProfile
Dim IE, objWMIService, strComputer, GroupDN, GroupCN
Dim lgCnt, oReg, strValueName, strKeyPath, intDebug, intHasIE ', oP

const HKEY_LOCAL_MACHINE = &H80000002

Set objNetwork = CreateObject("Wscript.Network")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objSysInfo = CreateObject("ADSystemInfo")
Set objShell = WScript.CreateObject("WScript.Shell")
Set colEnvVars = objShell.Environment("User")

strUserProfile = objShell.ExpandEnvironmentStrings("%USERPROFILE%")
strLogonServer = objShell.ExpandEnvironmentStrings("%LOGONSERVER%")
strUserDN = objSysInfo.UserName
strComputerDN = objSysInfo.ComputerName
strUserName = UCase((objNetwork.UserName))
strComputerName = UCase((objnetwork.ComputerName))

Set objUser = GetObject("LDAP://" & strUserDN)
Set objComputer = GetObject("LDAP://" & strComputerDN)
Set objShell = Wscript.CreateObject("Wscript.Shell")
intHasIE = 0
lgCnt = CLng(0)

intDebug = 0 'set to 1 to force stop/display on errors

On Error Resume Next
If intDebug=1 Then On Error Goto 0

Err.Clear
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")

strKeyPath = "SOFTWARE\Microsoft\Windows NT\CurrentVersion"
strValueName = "ProductName"
oReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strOS
Set oReg=nothing

' Display IE status window
Err.Clear
intHasIE = CreateIE()
If intHasIE Then
	showstat(strOS)
	showstat("Logon Script v1.0 " & Date() & " " & Time())
End If

' Get the User ID
Set WSHNetwork = WScript.CreateObject("WScript.Network")
strUser = ""
Do While strUser = ""
	strUser = WSHNetwork.UserName
Loop

If intHasIE Then 'populate header area
	IE.document.all.scrolling.InnerText = "Please wait while your logon script runs.         Please wait while your logon script runs." 
	IE.document.all.msg1.InnerText = strUser
	IE.document.all.msg2.InnerText = strComputerName
	IE.document.all.holdit.checked=False
End If


Call Main()


' Final Clean up ----------------------------------------
On Error Resume Next

If intHasIE Then
	IE.document.all.scrolling.InnerText = "Network Logon Completed..."
	showstat("Script Completed")
	' Close IE status window
	Wscript.Sleep 5000
	If Not IE.document.all.holdit.checked Then
		IE.quit()
	End If
End If

Set objGroupList = Nothing 'from LoadGroups(), IsMember()
Set objNetwork  = Nothing
Set objFSO      = Nothing
Set objSysInfo  = Nothing
Set objShell    = Nothing
Set colEnvVars  = Nothing
Set objUser     = Nothing
Set objComputer = Nothing
Set objShell    = Nothing
' ------------------------- done with login --------------






'=================================================================================================

Function CreateIE()'----------------------------------------
'return 0 if not created, 1=created.
Dim intCnt
On Error Resume Next
If intDebug=1 Then On Error Goto 0
CreateIE = 0
Err.Clear
Set IE = CreateObject("InternetExplorer.Application")
If Err.Number <> 0 Then Exit Function

With IE
	.navigate "\\"&strLogonServer&"\netlogon\tdlogon.htm"
	If Err.Number <> 0 Then Exit Function

	.resizable=0
	.height=400
	.width=375
	.left=150
	.top = 100
	.menubar=0
	.toolbar=0
	.statusBar=0
	.visible=1
End With

intCnt = 0
Do While IE.Busy
    	' wait for page to load
    	Wscript.Sleep 100
	intCnt = intCnt + 1
	If intCnt > 1000 Then Exit Do 'failsafe
Loop
CreateIE = 1
End Function '-----------------------------------------------




Sub Main() '==========================================================================
If InStr(UCase(strOS),"SERVER")=0 Then ' workstation processing --------------------
	showstat("Processing Workstation and Desktop..")

	' ************** Example of running a command line executable
	
	'If objFSO.FileExists("\\Fileserver\EzAudit\ezstart.exe") Then
	'showstat(" Computer Audit started.")
	'objShell.Run "cmd /c \\Fileserver\EzAudit\ezstart.exe /auto",0
	'End If

End If 'NOT a SERVER -------------------------------------



' ***********************************************************
' ***		    Map Common Network Drives   	  ***
' ***********************************************************
' Map a network drive If the user is a member of the group.
' Alert the user If the drive cannot be mapped.

strErrMsg = ""
If IsMember("Domain Admins") Then '--------------------

	
 showstat("Mapping Y: for FILESERVER\ADMINS$") 
 If Not MapDrive("Y:", "\\FILESERVER\ADMINS$") Then StrErrMsg = strErrMsg & vbCrLf & "Unable to Map Y: to FILESERVER\ADMINS$"
 End If 'Domain Admins

end if 'E$ exists

If IsMember("Quickbooks") Then
 showstat("Mapping Q: for Quickbooks") 
 If Not MapDrive("Q:", "\\FILESERVER\qbfiles") Then strErrMsg = strErrMsg & vbCrLf & "Unable to Map Q: to \\instructor2\qbfiles"
 End If ' Quickbooks


If strErrMsg <> "" Then
	showstat("*********************************************" & _
		   strErrMsg & vbCrLf & "*********************************************")
	MsgBox vbCrLf & VbCrLf & strErrMsg & VbCrLf & vbCrLf, 16, "Resource Unavailable"
End If

' *********************************
' ***	End of Drive Mappings	***
' *********************************


' ************************************************************
' ***	Setup Network Printers based on Group Membership   ***
' ************************************************************
'showstat("Removing Network Printers")
'on error resume next
'Set oP=objNetwork.EnumPrinterConnections
'lgCnt=oP.Count
'Do While lgCnt>0
'  objNetwork.RemovePrinterConnection oP.Item(lgCnt-1),True,True
'  lgCnt=lgCnt-2
'Loop 
' If IsMember("SOMEGROUP") or strUserName="SOMEUSER" Then
'showstat("Mapping OfficeJet K80 Printer") 
'objNetwork.AddWindowsPrinterConnection "\\OTTO\hpoffice"
' End If
' *********************************
' ***	End Printer Mappings	***
' *********************************


showstat( "Flushing DNS cache") 
objShell.Run "cmd /c ipconfig /flushdns",0
objShell.Run "cmd /c ipconfig /registerdns",0


' *****************************************
' ***	Check Home Directory Mappings	***
' *****************************************
showstat( "Validating Home Directory") 
If Not objFSO.folderexists("H:\") Then
  showstat( "Home H: Directory was not mapped or setup correctly.  Logging off")
 Wscript.Sleep 6000
 objshell.run "logoff.exe"
End If
End Sub '---------------------- end Main() ------------------------------------



Function showstat(strMessage)
If intHasIE Then
	On Error Resume Next
	strStatus=strMessage + VbCrLf + strStatus 
	IE.document.all.wstatus.InnerText = strStatus
	If intDebug=1 Then On Error Goto 0
End If
End Function


Function IsMember(strGroup)
' Function to test for group membership,
' returns True If the user or computer is a member of the group.
  If IsEmpty(objGroupList) Then
    Call LoadGroups
  End If
  IsMember = objGroupList.Exists(strGroup)
End Function


Sub LoadGroups() '------------------------------------------------
' Subroutine to populate dictionary object with group memberships.
' objUser is the user or computer object, with global scope.
' objGroupList is a dictionary object, with global scope.

  Dim arrbytGroups, j, arrstrGroupSids(), objGroup

  Set objGroupList = CreateObject("Scripting.Dictionary")
  objGroupList.CompareMode = vbTextCompare

  objUser.GetInfoEx Array("tokenGroups"), 0
  arrbytGroups = objUser.Get("tokenGroups")
  If TypeName(arrbytGroups) = "Byte()" Then
    ReDim arrstrGroupSids(0)
    arrstrGroupSids(0) = OctetToHexStr(arrbytGroups)
    Set objGroup = GetObject("LDAP://<SID=" & arrstrGroupSids(0) _
      & ">")
    objGroupList(objGroup.sAMAccountName) = True
    Set objGroup = Nothing
    Exit Sub
  End If
  If UBound(arrbytGroups) = -1 Then
    Exit Sub
  End If
  ReDim arrstrGroupSids(UBound(arrbytGroups))
  For j = 0 To UBound(arrbytGroups)
    arrstrGroupSids(j) = OctetToHexStr(arrbytGroups(j))
    Set objGroup = GetObject("LDAP://<SID=" & arrstrGroupSids(j) _
      & ">")
    objGroupList(objGroup.sAMAccountName) = True
  Next
  Set objGroup = Nothing
End Sub '------------------------------------------------------------



Function MapDrive(strDrive, strShare)'--------------------------------------
' Function to map network share to a drive letter.
' If User/Password needed, set strShare as bar delimited string "Path|User|Password"
' If the drive letter specified is already in use, the function
' attempts to remove the network connection.
' objFSO is the File System Object, with global scope.
' objNetwork is the Network object, with global scope.
' Returns True If drive mapped, False otherwise.

Dim objDrive, tmparr, strLogon, strPW

If InStr(strShare,"|")<>0 Then
	tmparr=split(strShare,"|")
	strShare=tmparr(0):strLogon=tmparr(1):strPW=tmparr(2)
End If
On Error Resume Next
If intDebug=1 Then On Error GoTo 0
Err.Clear
If objFSO.DriveExists(strDrive) Then
    Set objDrive = objFSO.GetDrive(strDrive)
    If Err.Number <> 0 Then
      Err.Clear
      MapDrive = False
      Exit Function
    End If
    If CBool(objDrive.DriveType = 3) Then
      objNetwork.RemoveNetworkDrive strDrive, True, True
    Else
      MapDrive = False
      Exit Function
    End If
    Set objDrive = Nothing
End If
If strLogon <> "" Then 
	objNetwork.MapNetworkDrive strDrive, strShare, False, strLogon, strPW 
Else 
	objNetwork.MapNetworkDrive strDrive, strShare
End If
If Err.Number = 0 Then
    MapDrive = True
Else
    Err.Clear
    MapDrive = False
End If
If intDebug=1 Then On Error GoTo 0
End Function '-------------------------------------

Function OctetToHexStr(arrbytOctet)
' Function to convert OctetString (byte array) to Hex string.
  Dim k
  OctetToHexStr = ""
  For k = 1 To Lenb(arrbytOctet)
    OctetToHexStr = OctetToHexStr _
      & Right("0" & Hex(Ascb(Midb(arrbytOctet, k, 1))), 2)
  Next
End Function

<html>
<head>
<title>Company Logon</title>
<style type="text/css" media="all">
body {margin:0px;padding:0px;background-color:#E3E8E3;
      font-family:font-family:Verdana,Arial,'Comic Sans MS';font-size:10pt;}
td{font-size:10pt;color:black;font-weight:normal;}
textarea{
   font-family:arial;font-size:8pt;font-weight:bold;
   color:#000000;padding-left:4px;}
</style>
</head>
<body language="VBSCRIPT" SCROLL="no">
<table width="100%" cellspacing="0" cellpadding="0" border="0">
 <tr width="100%">
  <td colspan="2" style="width:100%;text-align:center;background-color:#FFFFFF;padding-top:4px;border-bottom:2px solid dimgray;">
   <img border="0" src="companylogo.jpg" width="400" height="86"></td>
 </tr>
 <tr>
  <td colspan="2" style="width:100%;padding-top:4px;text-align:center;font-size:12pt;
      font-weight:bold;font-family:font-family:'Comic Sans MS',Verdana,Arial;">
   Welcome to Company XYZ!
  </td>
 </tr>
 <tr>
  <td colspan="2" style="width:100%;padding-top:2px;text-align:center;font-size:9pt;">
   Network Logon...
  </td>
 </tr>
 <tr>
  <td style="width:50%;padding-top:2px;padding-right:8px;text-align:right;">User Name:</td>
  <td style="width:50%;font-family:Verdana;font-weight:bold;" id="Msg1" name="Msg1"></td>
 </tr>
 <tr>
  <td style="width:50%;padding-top:2px;padding-right:8px;text-align:right;">Computer Name:</td>
  <td style="width:50%;"><font style="font-weight:bold;" id="Msg2" name="Msg2"></font></td>
 </tr>
 <tr>
  <td colspan="2" style="width:100%;padding-top:4px;text-align:center;">
   <marquee id="scrolling" name="scrolling" width="75%" height="16" style='font-size:9pt;color:dimgray;'></marquee>
  </td>
 </tr>
 <tr>
  <td colspan="2" style="text-align:center;padding-top:5px;">
   <textarea rows="9" id="wstatus" name="wstatus" cols="60"></textarea></td>
 </tr>
 <tr>
  <td colspan="2" style='padding-left:15px;padding-top:4px;font-size:8pt;font-weight:normal;font-family:Arial;Verdana;color:gray;'>
   <input language="VBSCRIPT" type="checkbox" name="holdit" id="holdit" checked=""></input> 
   Click to leave window open
 </tr>
</table>
</body>
</html>

quote:

---

Originally posted by SAPIENScripter

From what I can tell, IE8 has some architectural changes that might break scripts like yours. IE8 has a compatibility mode you might need to experiment with.

---